幾個AutoHotkey的實用範例：音量控制、滾輪回上層與語音功能（AHK #7）

tkey

音量控制

使用標準的101鍵或104鍵鍵盤時，不像筆記型電腦通常都有多媒體按鍵，此時我們可以用下列AutoHotkey腳本以使用按鍵來控制音量：

!NumpadAdd:: Send {Volume_Up} ;//Alt + numpad plus
!NumpadSub:: Send {Volume_Down} ;//Alt + numpad minus
!Numpad0::Send {Volume_Mute} ;//Alt + numpad 0 

檔案總管回上層目錄

按下滑鼠中鍵（滾輸）往上層目錄或到下個項目

~MButton::
  WinGetClass,sClass,A
  ;//MsgBox class=%sClass%
  ;//FM=7-zip window, TFcFormMain=FreeCommander
  if (sClass="TFcFormMain" || sClass="FM" || sClass="MultiCommander MainWnd") {
    Send, {BS}
  } else if (sClass="CabinetWClass") {
    Send, !{up}
  } else if (sClass="MozillaWindowClass" || sClass="Chrome_WidgetWin_1") {
    WinGetTitle, sTitle, A
    ;//MsgBox title=%sTitle%
    if (InStr(sTitle, "Gmail") > 0) {
      Send {j}
    } else if (InStr(sTitle, "Twitter") > 0) {
      Send {j}
    }
  } 
  return

~+MButton::
  WinGetClass,sClass,A
  ;//MsgBox $%sClass%$
  if (sClass = "MozillaWindowClass" || sClass="Chrome_WidgetWin_1") {
    WinGetTitle, sTitle, A
    if (InStr(sTitle, "Gmail") > 0 || InStr(sTitle, "Facebook") > 0) {
      Send {k}
    } else if (InStr(sTitle, "Twitter") > 0) {
      Send {k}
    }
  }
  return

取游標位置的顏色代碼

用MouseGetPos取得游標座標，再用PixelGetColor取出座標處的顏色代碼

!a::
  MouseGetPos, MouseX, MouseY
  PixelGetColor, color, %MouseX%, %MouseY%, RGB  
  Clipboard := "#" . SubStr(color, 3)
  MsgBox, Current color is `n %Clipboard%
  return

叫用語音API

A_YYYY、A_Hour等是AutoHotkey的內建變數。

!F12::
  date = %A_YYYY%年%A_MM%月%A_DD%日
  Speak("今天日期是 " . date)
  time = %A_Hour%點 %A_Min%分 %A_Sec%秒
  Speak("現在時間是 " . time)
  return

Speak(say) {
  spovice:=ComObjCreate("sapi.spvoice")
  spovice.Speak(say)
}

實際操作影片

＃＃

您可能也會有興趣的類似文章

• AutoHotkey腳本的４種除錯方法（AHK #5） (0則留言, 2019/05/25)
• 輕鬆學會AutoHotkey的熱鍵：熱鍵用法實例解說（AHK #4） (0則留言, 2019/05/24)
• AutoHotkey與Google+ Commander合用－以滑鼠移動訊息位置 (0則留言, 2011/10/31)
• [Tools] 常用的AutoHotKey設定 (9則留言, 2005/05/12)
• 用AutoHotkey統一不同工具的偵錯功能鍵 (0則留言, 2008/03/19)
• [Mattermost 教學#5] 方便的斜線命令與AutoHotkey (0則留言, 2018/04/17)
• AutoHotkey：在FireFox裡用鍵盤瀏覽網頁 (2則留言, 2008/03/27)
• 用AutoHotkey改造ThinkPad X61按鍵 (2則留言, 2008/03/23)
• 改寫AutoHotkey輸出中文字串的寫法 (4則留言, 2009/06/20)
• 快速建立個人常用詞庫－AutoHotkey 熱字串小工具：HotString Helper（AHK #3） (0則留言, 2019/05/18)
• 輕鬆學會彈指神功－揭露AutoHotkey絕技 (59則留言, 2008/04/10)
• AutoHotkey輸出中文的方法 (16則留言, 2008/03/01)
• [AutoHotkey] 在檔案總管裡按滑鼠滾輪切換到上層資料夾 (3則留言, 2011/06/23)
• 用AutoHotkey防止因按Esc鍵而不慎誤關視窗 (0則留言, 2011/04/01)
• [Tools] 操作熱鍵與熱字串的超便利工具：AutoHotKey (13則留言, 2005/04/29)